実はmxmlは触ったことなかったのですが、ちょっとやってみようかなと思ってしまいました。

adobeさんも協賛しているらしくお土産をいっぱいもらいました。
クラス図カレンダー当った！
Flash Catalystの紹介をされてましたが、かなり高機能そうで今後に期待ですね。

あと、あのSaqooshaさんとFLARToolKitの実演がみれて感動しました。
大阪の人だったんだなあ。会社も近そうだしteracoってのにも参加してみようかな。。

3dyurameki2.swf

先日のエントリーで布がゆらめくような動きが表現してみましたが、今回は縦の動きも追加してみました。
物理学的にはデタラメな動きなんでしょうけどそれなりに布っぽくなったかな。。

画面クリックでマテリアル切替。

テクスチャに使ってる画像は下記のサイトのものを利用しました。
CG Tectures

package
{
	import caurina.transitions.Tweener;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.papervision3d.cameras.CameraType;
	import org.papervision3d.core.proto.CameraObject3D;
	import org.papervision3d.materials.BitmapFileMaterial;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;

	/**
	 *
	 * @author modoki
	 */
	public class Main extends BasicView
	{
		private var mainObj:Plane;
		private var si:Number = 0.5;
		private var ROWS:int = 10;
		private var COLS:int = 20;
		private var material_a:BitmapFileMaterial;
		private var material_b:WireframeMaterial;

		public function Main():void
		{
			super(400, 400, true, true, CameraType.FREE);

			//-----------------------------
			// 初期カメラ設定
			//-----------------------------
			iniCam();

			//-----------------------------
			// MATERIAL
			//-----------------------------
			material_a = new BitmapFileMaterial("./img/golira.jpg");
			material_b = new WireframeMaterial();
			material_a.doubleSided = true;
			material_b.doubleSided = true;

			//-----------------------------
			// OBJECT
			//-----------------------------
			mainObj = new Plane(material_a, 600, 600, COLS, ROWS);
			mainObj.rotationY = 20;
			scene.addChild(mainObj);

			// Handler
			stage.addEventListener(MouseEvent.MOUSE_UP, clickHandler);

			// レンダリング開始
			startRendering();
		}

		/**
		 *-------------------------------------------------------
		 * カメラ初期化
		 *-------------------------------------------------------
		 */
		private function iniCam():void
		{
			// カメラ開始位置
			camera.moveBackward(4000);
			camera.moveUp(1000);
			camera.culled = true;

			// カメラ初期位置設定
			var iniCam:CameraObject3D = new CameraObject3D();
			iniCam.moveUp(400);

			// カメラ開始から初期位置まで移動
			Tweener.addTween( camera, {
				x			:iniCam.x,
				y			:iniCam.y,
				z			:iniCam.z,
				rotationX	:iniCam.rotationX,
				rotationY	:iniCam.rotationY,
				rotationZ	:iniCam.rotationZ,
				time		:5,
				transition	:"easeInOut"
				} );
		}

		/**
		 *-------------------------------------------------------
		 * Click
		 *-------------------------------------------------------
		 */
		private function clickHandler(e:MouseEvent):void
		{
			if (mainObj.material == material_a) {
				mainObj.material = material_b;
			} else {
				mainObj.material = material_a;
			}
		}

		/**
		 *-------------------------------------------------------
		 * onRenderTick
		 *-------------------------------------------------------
		 */
		override protected function onRenderTick(event:Event = null):void {
			si += 5;

			for ( var i:String in mainObj.geometry.vertices ) {
				var j:int = Number(i);

				mainObj.geometry.vertices[i].z = (Math.cos(Math.PI / 180 * (si * (j % (ROWS + 1)))) + 1) * 30;
				mainObj.geometry.vertices[i].y = (j % (ROWS + 1)) * ((Math.sin(Math.PI / 180 * (si + j)) + 2) * 30);
			}

			mainObj.pitch(1);

			super.onRenderTick(event);
		}
	}
}

3dmawaruita.swf

Papervision3D使ってて3Dっぽい動きを表現したくて複数のPlaneをY軸回転させてみました。
こんなのが簡単につくれるからいいですね。
画像読み込んだりしたらおもしろそうだなー。

操作方法:
MOUSE:←→:左右回転
MOUSE:wheel:ズーム・ズームアウト
PlaneクリックでそのPlaneにポップアップ

package
{
	import caurina.transitions.Tweener;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filters.GlowFilter;
	import org.papervision3d.cameras.CameraType;
	import org.papervision3d.core.proto.CameraObject3D;
	import org.papervision3d.events.InteractiveScene3DEvent;
	import org.papervision3d.materials.ColorMaterial;
	import org.papervision3d.materials.special.CompositeMaterial;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;
	import org.papervision3d.view.layer.ViewportLayer;

	/**
	 *
	 * @author modoki
	 */
	public class Main extends BasicView
	{
		private var myPlane:Plane;
		private var mainObj:DisplayObject3D;
		private var selectObjName:String;
		private var onPopup:Boolean = false;
		private var onMaterial:ColorMaterial;
		private var floor:Plane;

		public function Main():void
		{
			super(400, 400, true, true, CameraType.FREE);
			buttonMode = true;

			//-----------------------------
			// 初期カメラ設定
			//-----------------------------
			iniCam();

			//-----------------------------
			// MATERIAL
			//-----------------------------
			onMaterial = new ColorMaterial(0x000099, 0.8);
			onMaterial.doubleSided = true;
			onMaterial.interactive = true;

			var material:CompositeMaterial = new CompositeMaterial();
			material.addMaterial(new ColorMaterial(0xCCCCCC, 0.8));
			material.doubleSided = true;
			material.interactive = true;

			//-----------------------------
			// OBJECT
			//-----------------------------
			mainObj = new DisplayObject3D();
			scene.addChild(mainObj);

			floor = new Plane(new WireframeMaterial(), 800, 800, 5, 5);
			floor.rotationX = 90;
			scene.addChild(floor);

			for (var i:int = 0; i < 50; i++) {
				var myPlane:Plane = new Plane(material, 50, 80, 2, 2);

				// 板配置
				myPlane.name = "plane" + i;
				myPlane.x = Math.random() * 600 - 300;
				myPlane.y = Math.random() * 150;
				myPlane.z = Math.random() * 600 - 300;

				// 中心に向かせる
				//myPlane.lookAt(mainObj);
				myPlane.rotationY = Math.atan2(myPlane.x, myPlane.z) * 180 / Math.PI;

				myPlane.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, clickHandler);
				myPlane.addEventListener(InteractiveScene3DEvent.OBJECT_OVER, overHandler);
				myPlane.addEventListener(InteractiveScene3DEvent.OBJECT_OUT, outHandler);

				mainObj.addChild(myPlane);
			}

			stage.addEventListener(MouseEvent.MOUSE_WHEEL, onMouseWheel);

			// レンダリング開始
			startRendering();
		}

		/**
		 *-------------------------------------------------------
		 * カメラ初期化
		 *-------------------------------------------------------
		 */
		private function iniCam():void
		{
			// カメラ開始位置
			camera.moveBackward(3000);
			camera.moveUp(1000);
			camera.culled = true;

			// カメラ初期位置設定
			var iniCam:CameraObject3D = new CameraObject3D();
			iniCam.moveUp(500);
			iniCam.rotationX = 20;

			// カメラ開始から初期位置まで移動
			Tweener.addTween( camera, {
				x			:iniCam.x,
				y			:iniCam.y,
				z			:iniCam.z,
				rotationX	:iniCam.rotationX,
				rotationY	:iniCam.rotationY,
				rotationZ	:iniCam.rotationZ,
				time		:5,
				transition	:"easeInOut"
				} );
		}

		/**
		 *-------------------------------------------------------
		 * Handler
		 *-------------------------------------------------------
		 */
		private function onMouseWheel(e:MouseEvent):void
		{
			var target :DisplayObject3D = new DisplayObject3D();
			target.copyTransform( camera );

			if (e.delta > 0) {
				target.moveForward(200);
			}else {
				target.moveBackward(200);
			}

			Tweener.addTween( camera, {
				x			:target.x,
				y			:target.y,
				z			:target.z,
				time		:1,
				transition	:"easeInOut"
				} );
		}		

		/**
		 *-------------------------------------------------------
		 * Handler
		 *-------------------------------------------------------
		 */
		private function overHandler(e:InteractiveScene3DEvent):void
		{
			// フィルター効果つける
			var vpl:ViewportLayer = e.currentTarget.createViewportLayer(viewport, true);
			vpl.filters = [new GlowFilter(0xffffff, 0.5, 10, 10, 5)];
		}

		/**
		 *-------------------------------------------------------
		 * Handler
		 *-------------------------------------------------------
		 */
		private function outHandler(e:InteractiveScene3DEvent):void
		{
			// フィルター効果はずす
			var vpl:ViewportLayer = e.currentTarget.createViewportLayer(viewport, true);
			vpl.filters = null;
		}

		/**
		 *-------------------------------------------------------
		 * Handler
		 *-------------------------------------------------------
		 */
		private function clickHandler(e:InteractiveScene3DEvent):void
		{
			// Popアップ中
			onPopup = true;

			// Camera移動用ターゲット準備
			var target :DisplayObject3D = new DisplayObject3D();

			if (selectObjName != null) {
				// 前のオブジェクトは前の位置に戻る
				var oldObj:DisplayObject3D = mainObj.getChildByName(selectObjName);
				Tweener.addTween( oldObj, {
					y			:0,
					scale       :1,
					time		:1,
					transition	:"easeOutElastic"
					} );

				// 一度選択済み
				oldObj.material = onMaterial;
			}

			if (selectObjName != e.currentTarget.name) {
				// 前と違うオブジェクトをクリック

				target.copyTransform( e.currentTarget );
				target.moveBackward( camera.zoom * camera.focus - 100);
				target.moveUp(250);

				Tweener.addTween( mainObj, {
					rotationX	:0,
					rotationY	:0,
					rotationZ	:0,
					time		:1,
					transition	:"easeInOut"
					} );

				Tweener.addTween( camera, {
					x			:target.x,
					y			:target.y,
					z			:target.z,
					rotationX	:30,
					rotationY	:e.currentTarget.rotationY,
					rotationZ	:e.currentTarget.rotationZ,
					time		:1,
					transition	:"easeInOut"
					} );

				Tweener.addTween( e.currentTarget, {
					y			:e.currentTarget.y + 100,
					scale       :3,
					delay       :0.5,
					time		:2,
					transition	:"easeOutElastic"
					} );

				selectObjName = e.currentTarget.name;
			} else {
				// 前と同じオブジェクトをクリック

				target.copyTransform( camera );
				target.moveBackward(350);

				Tweener.addTween( camera, {
					x			:target.x,
					y			:target.y,
					z			:target.z,
					time		:1,
					transition	:"easeInOut"
					} );

				onPopup = false;
				selectObjName = null;
			}
		}

		/**
		 *-------------------------------------------------------
		 * onRenderTick
		 *-------------------------------------------------------
		 */
		override protected function onRenderTick(event:Event = null):void {
			if (!onPopup){
				mainObj.yaw(-(mouseX - stage.width * .5) / (stage.width * .1));
				floor.roll(-((mouseX - stage.width * .5) / (stage.width * .25)));
			}

			super.onRenderTick(event);
		}
	}
}

3dcoolirismodoki.swf

画像検索してかっこよく一覧で表示してくれるブラウザのプラグインに「Cooliris」というものがありますが、こちらの画像表示部分の操作が気持ち良いのでFlash + Papervision3Dで同じようなものを作成してみた。
ほんとは検索部分とか実装してみたいのですが、そこはおいおい対応ということで。。

操作方法:
KEY:←→↑↓:それぞれの方向のPlaneに移動
KEY:CONTROL:ランダムなPlaneに移動
PlaneクリックでそのPlaneに移動

ターゲットのPlaneとカメラのX座標の距離が長ければカメラの角度を大きく、短ければ角度を小さくする。

package {
	import caurina.transitions.Tweener;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.ui.Keyboard;
	import org.papervision3d.cameras.CameraType;
	import org.papervision3d.events.InteractiveScene3DEvent;
	import org.papervision3d.materials.ColorMaterial;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;

	public class Main extends BasicView
	{
		private var mainObj:DisplayObject3D;
		private var tget:DisplayObject3D = new DisplayObject3D();;
		private	var photoNum:int = 0;
		private var oldPhotoNum:int = -1;
		private	var photoCount:int = 0;
		private const ROWS:int = 4;

		public function Main()
		{
			super(800, 600, true, true, CameraType.FREE);
			buttonMode = true;

			mainObj = scene.addChild(new DisplayObject3D("mainObj"));

			// Material
			//var fmt:FogMaterial = new FogMaterial(0x000000);
			//renderer.filter = new FogFilter(fmt, 10, 50, 2000);
			var material:ColorMaterial = new ColorMaterial(0x666666, 0.8, true);

			for (var i:int = 0; i < 52; i++)
			{
				photoCount++;

				var myPlane:Plane = new Plane(material, 80, 50, 2, 2);
				myPlane.name = "photo" + i;
				myPlane.x = int(i / ROWS) * 90;
				myPlane.y = (i % ROWS) * -60;
				myPlane.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, onObjectClick);
				mainObj.addChild(myPlane);
			}

			// 初期0番目
			movePhoto(0);

			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);

			startRendering();
		}

		//--------------------------------
		// 画像へ移動処理
		//--------------------------------
		private function movePhoto(num:int):void
		{
			num = Math.min(photoCount - 1, num);
			num = Math.max(0, num);
			photoNum = num

			var tmp:DisplayObject3D = mainObj.getChildByName("photo" + num);
			tget.copyTransform(tmp);
			tget.moveBackward(200);

			Tweener.addTween(camera, {
				x:tget.x
				, y:tget.y
				, z:tget.z
				, time:4.0
				, transition:"easeInOut" } );

			Tweener.addTween(tmp, {
				z:tmp.z - 50
				, time:1.0
				, transition:"easeOutElastic" } );

			Tweener.addTween(mainObj.getChildByName("photo" + oldPhotoNum), {
				z:0
				, time:0.5
				, transition:"easeIn" } );

			oldPhotoNum = num;
		}

		//--------------------------------
		// Handler:クリック処理
		//--------------------------------
		private function onObjectClick(e:InteractiveScene3DEvent):void
		{
			movePhoto(e.target.name.replace("photo", ""));
		}

		//--------------------------------
		// Handler:毎フレーム処理
		//--------------------------------
		override protected function onRenderTick(event:Event = null):void
		{
			var deg:Number = Math.min(60, (tget.x - camera.x) * 0.1);
			deg = Math.max( -60, deg);
			camera.rotationY = deg;

			super.onRenderTick(event);
		}

		//--------------------------------
		// Handler:キーダウン処理
		//--------------------------------
		private function onKeyDown(event:KeyboardEvent):void
		{
			switch (event.keyCode) {
				case Keyboard.RIGHT:
					photoNum += ROWS;
					break;
				case Keyboard.LEFT:
					photoNum -= ROWS;
					break;
				case Keyboard.UP:
					photoNum--;
					break;
				case Keyboard.DOWN:
					photoNum++;
					break;
				case Keyboard.CONTROL:
					photoNum = Math.floor(Math.random() * photoCount);
					break;
			}

			movePhoto(photoNum);
		}
	}
}

3dyurameki.swf

　Paparvision3dで各ポリゴンの頂点をいじれるので、三角関数など規則性のある関数で処理してみたら布がゆらめくような動きが表現できました。なかなか面白い。
画面クリックでマテリアル切替。

package
{
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.papervision3d.cameras.CameraType;
	import org.papervision3d.core.proto.LightObject3D;
	import org.papervision3d.materials.shadematerials.GouraudMaterial;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;

	/**
	 *
	 * @author modoki
	 */
	public class Main extends BasicView
	{
		private var mainObj:Plane;
		private var si:Number = 0;
		private var material_a:GouraudMaterial;
		private var material_b:WireframeMaterial;

		public function Main():void
		{
			super(600, 600, true, true, CameraType.FREE);

			// カメラ設定初期化
			camera.moveForward(200);
			camera.moveUp(400);
			camera.rotationX = 20;

			// ライト設定
			var light:LightObject3D = new LightObject3D();
			light.x = -500;
			light.y = 500;

			// Material
			material_a = new GouraudMaterial(light, 0xFFFFFF, 0x0000FF);
			material_b = new WireframeMaterial();
			material_a.doubleSided = true;
			material_b.doubleSided = true;

			// DisplayObject
			mainObj = new Plane(material_a, 800, 500, 10, 5);
			mainObj.rotationX = 90;
			scene.addChild(mainObj);

			// Handler
			stage.addEventListener(MouseEvent.MOUSE_UP, clickHandler);

			// レンダリング開始
			startRendering();
		}

		/**
		 *-------------------------------------------------------
		 * Click
		 *-------------------------------------------------------
		 */
		private function clickHandler(e:MouseEvent):void
		{
			if (mainObj.material == material_a) {
				mainObj.material = material_b;
			} else {
				mainObj.material = material_a;
			}
		}

		/**
		 *-------------------------------------------------------
		 * onRenderTick
		 *-------------------------------------------------------
		 */
		override protected function onRenderTick(event:Event = null):void {
			// 回転
			mainObj.roll(-((mouseX - stage.width * .5) / (stage.width * .25)));

			// ゆらめき
			si += 10;
			for ( var i:String in mainObj.geometry.vertices ) {
				mainObj.geometry.vertices[i].z = Math.cos((si + (Number(i) * 5)) * Math.PI / 180) * 100;
			}

			super.onRenderTick(event);
		}
	}
}

みたところPHPやJavaScriptはハイライト対応しているようだけどActionScriptが対応していない。。。なんと。
なのでActionScript用のものはなにかないか～っと探したところ「SyntaxHighlighter」のAS拡張作っている人がいました。

AS3 Syntax Highlighting (with SyntaxHighlighter)

基本的に上のサイトに書いてある通り、「SyntaxHighlighter.css」を置き換え、「shBrushAS3.js」を追加します。
その後「syntaxhighlighter.php」のlunguage設定にAS用の文字列を追加。

		$this->languages = apply_filters( 'agsyntaxhighlighter_languages', array(
			'cpp'        => 'shBrushCpp.js',
			'c'          => 'shBrushCpp.js',
			'c++'        => 'shBrushCpp.js',
			'c#'         => 'shBrushCSharp.js',
			'c-sharp'    => 'shBrushCSharp.js',
			'csharp'     => 'shBrushCSharp.js',
			'css'        => 'shBrushCss.js',
			'delphi'     => 'shBrushDelphi.js',
			'pascal'     => 'shBrushDelphi.js',
			'java'       => 'shBrushJava.js',
			'js'         => 'shBrushJScript.js',
			'jscript'    => 'shBrushJScript.js',
			'javascript' => 'shBrushJScript.js',
			'php'        => 'shBrushPhp.js',
			'py'         => 'shBrushPython.js',
			'python'     => 'shBrushPython.js',
			'rb'         => 'shBrushRuby.js',
			'ruby'       => 'shBrushRuby.js',
			'rails'      => 'shBrushRuby.js',
			'ror'        => 'shBrushRuby.js',
			'sql'        => 'shBrushSql.js',
			'vb'         => 'shBrushVb.js',
			'vb.net'     => 'shBrushVb.js',
			'xml'        => 'shBrushXml.js',
			'html'       => 'shBrushXml.js',
			'xhtml'      => 'shBrushXml.js',
			'xslt'       => 'shBrushXml.js',
			'as'         => 'shBrushAS3.js', //これ追加
		) );

これで下記のようにActionScriptがハイライト表示されるようになりました。

package {
    public class Main
    {
        public function Main() extends Sprite
        {
            trace("test");
        }
    }
}

Warning: htmlspecialchars_decode() expects parameter 1 to be string, NULL given in ～

情報がないか探してみたけど国内でなかったので海外調べてみたところ、どうやらWordPressのバグのようです。

下記リンク先の方法でファイルを書き換えたところ問題解決！
http://core.trac.wordpress.org/ticket/9090